ReadCurrTime:   ;Считать текущее время
              mov    R1,#2                     ;Cекунды в RTC
              mov    R5,#5                     ;Колво байт
              mov    R0,#CurrSec               ;Начало буфера в озу
              jmp    ReadTimerB                ;Чтение таймера

TimerInit:    ;Инициализация таймера
              mov    R5,#0
              mov    A,#00000000b
              jmp    WriteTimer


//Это типа настройка будильника по INT
ReloadTimer: ;Запуск таймера на нужное колво дискрет
              ;инкримент секунд
              call   TimerInit
              mov    R5,#8
              mov    A,#10010000b
              call   WriteTimer                ;Установка рещима таймера
              mov    AlmHu,#55h
              mov    AlmMin,CurrMin
              mov    AlmHour,CurrHour
              mov    A,CurrSec
              add    A,#01h
              da     A
              mov    AlmSek,A
              cjne   A,#60h,$+3
              jc     1$
              mov    AlmSek,#0
              mov    A,CurrMin
              add    A,#01h
              da     A
              mov    AlmMin,A
              cjne   A,#60h,$+3
              jc     1$
              mov    AlmMin,#0
              mov    A,CurrHour
              anl    A,#00111111b
              add    A,#01h
              da     A
              cjne   A,#24h,$+3
              jc     2$
              clr    A
2$:           mov    AlmHour,A
              mov    A,CurrHour
              anl    A,#11000000b
	      orl    AlmHour,A


1$:          ;Записать это в таймер
              mov    R0,#AlmHu  ;Начало в ОЗУ
              mov    R1,#09h    ;Начало в таймере
              mov    R5,#4      ;Колво байт
              call   WriteTimerB
              mov    R5,#0
              mov    A,#4
              jmp    WriteTimer                ;Сброс внешнего прирывания