Отправлено =AVR= 25 октября 2006 г. 18:37 В ответ на: Ответ: Спасибо посмотрю отправлено <font color=gray>link</font> 25 октября 2006 г. 17:32

Процедура прерывания таймера, реализующая 8-канальный 256-зубый ШИМ. Безвозвратно тратится 10 регистров из 32 (R1 (tmp) - рабочий, R2 (pwm) - пила ШИМа, R3..R10 - уставки ШИМ). Таймер в режиме CTC - Clear On Compare (реинициализация и сброс флага автоматические). Занимает 30 тактов вместе со входом/возвратом, максимальная частота ШИМ - 2.6 КГЦ при 20-МГЦ кварце. Если выбрать частоту ШИМ порядка 500 ГЦ (порядка 8 мкс на 1 ступеньку), то останется свободно 80% процессорного времени, а если сделать меньше ступенек - то гораздо больше:

t0isrREG:
	in	stsav,SREG	;Сохраняем статус. STSAV - общий для всех невложенных прерываний
 
	inc	pwm		;Добавляем очередной зуб к пиле ШИМ
 
	cp	r3,pwm		;Перенос=1 при Rx <= PWM		;Те же 2 такта на канал, что и у ПИКа
	rol	tmp		;Вдвигаем перенос в рабочий регистр	;
	cp	r4,pwm		;Перенос=1 при Rx <= PWM
	rol	tmp		;Вдвигаем перенос в рабочий регистр
	cp	r5,pwm		;Перенос=1 при Rx <= PWM
	rol	tmp		;Вдвигаем перенос в рабочий регистр
	cp	r6,pwm		;Перенос=1 при Rx <= PWM
	rol	tmp		;Вдвигаем перенос в рабочий регистр
	cp	r7,pwm		;Перенос=1 при Rx <= PWM
	rol	tmp		;Вдвигаем перенос в рабочий регистр
	cp	r8,pwm		;Перенос=1 при Rx <= PWM
	rol	tmp		;Вдвигаем перенос в рабочий регистр
	cp	r9,pwm		;Перенос=1 при Rx <= PWM
	rol	tmp		;Вдвигаем перенос в рабочий регистр
	cp	r10,pwm		;Перенос=1 при Rx <= PWM
	rol	tmp		;Вдвигаем перенос в рабочий регистр
  
	out	PORTA,tmp	;Выставляем ноги PWM 1..8
 
	out	SREG,stsav	;Восстанавливаем статус
  
	reti

• http://caxapa.ru/67267.html

• Ответ: Спасибо — link   (25.10.2006 19:20 194.176.97.137, пустое)
  • Можно загрубить ШИМ с 256 до 128/64/32/16 ступенек, объявив pwm'ом один из старших регистров (типа r17) и заменив команду inc pwm командой subi pwm,-2/-4/-8/-16 соответственно — =AVR=   (25.10.2006 19:55 80.92.96.19, пустое)